Cách sử dụng hàm IF trong Google Sheets chi tiết, hiệu quả

Hàm IF trong Google Sheets là hàm logic cơ bản, dùng để kiểm tra điều kiện và trả về kết quả tương ứng. Nhờ khả năng kết hợp với nhiều hàm khác, IF được sử dụng rộng rãi trong xử lý dữ liệu, phân loại kết quả và tự động hóa bảng tính. Bài viết này sẽ hướng dẫn cách dùng hàm IF và các trường hợp áp dụng phổ biến.

Hướng dẫn chi tiết cách sử dụng hàm IF trong Google Sheets

Hàm IF trong Google Sheets là một hàm logic dùng để kiểm tra một điều kiện và trả về kết quả khác nhau tùy theo điều kiện đó đúng (TRUE) hay sai (FALSE).

Cú pháp của hàm IF: =IF(điều_kiện, giá_trị_nếu_đúng, giá_trị_nếu_sai)

Trong đó:

• điều_kiện: Một phép so sánh (>, <, =, >=, <=, <>)
• giá_trị_nếu_đúng: Kết quả trả về khi điều kiện đúng
• giá_trị_nếu_sai: Kết quả trả về khi điều kiện sai

Kiểm tra 1 điều kiện đơn

Ví dụ 1: Giả sử bạn có một bảng điểm, trong đó ô F2 chứa điểm trung bình của học sinh. Bạn muốn xác định xem học sinh đó đậu hay rớt dựa trên điều kiện điểm trung bình từ 5 trở lên thì đậu.

Khi áp dụng công thức: =IF(F2>=5;"Đậu";"Rớt")

Google Sheets sẽ tự động kiểm tra giá trị trong ô F2.

• Nếu điểm trung bình lớn hơn hoặc bằng 5, kết quả hiển thị là Đậu.
• Nếu điểm nhỏ hơn 5, kết quả trả về là Rớt.

Áp dụng hàm IF để phân loại kết quả học sinh

Kiểm tra nhiều điều kiện

Ví dụ 2: Bạn có điểm trung bình của học sinh được nhập tại ô F3 và muốn xếp loại học lực dựa trên mức điểm đạt được.

Công thức: =IF(F3>=8;"Giỏi";IF(F3>=6,5;"Khá";"Trung bình"))

Cách xử lý của công thức:

• Trường hợp điểm trung bình tại ô F3 từ 8 trở lên, kết quả được xếp loại Giỏi.
• Nếu điểm chưa đạt 8, hệ thống tiếp tục kiểm tra điều kiện kế tiếp:
• Điểm từ 6,5 trở lên sẽ được xếp loại Khá.
• Những trường hợp còn lại (dưới 6,5) sẽ được phân loại là Trung bình.

Cách dùng hàm IF để kiểm tra nhiều điều kiện

Hàm IF khi kết hợp với COUNTIF thường được dùng để kiểm tra số lần xuất hiện của một giá trị trong một vùng dữ liệu, từ đó đưa ra kết luận hoặc thông báo phù hợp.

Ví dụ 3: Giả sử bạn có một bảng danh sách doanh thu, trong đó cột B là Tên sản phẩm và cột E dùng để xác định sản phẩm đó có phải bán lần đầu hay không.

Để kiểm tra xem tên sản phẩm tại ô B2 đã từng xuất hiện trước đó hay chưa, bạn sử dụng công thức sau tại ô C2:

=IF(COUNTIF($B$2:B2;B2)=1;"Lần đầu tiên";"")

Giải thích:

• COUNTIF($B$2:B2;B2) đếm số lần sản phẩm ở ô B2 xuất hiện trong danh sách từ dòng 2 đến dòng hiện tại.
• Nếu kết quả bằng 1, nghĩa là sản phẩm này xuất hiện lần đầu → Hiển thị “Lần đầu tiên”.
• Nếu lớn hơn 1, tức là sản phẩm đã xuất hiện trước đó → Không hiển thị gì.

Hàm IF kết hợp với COUNTIF giúp đếm và xử lý dữ liệu theo điều kiện

Hàm IF khi kết hợp với INDEX và MATCH thường được sử dụng để dò tìm dữ liệu theo điều kiện, sau đó đưa ra kết quả đánh giá hoặc phân loại phù hợp. Cách kết hợp này đặc biệt hữu ích khi dữ liệu không nằm cố định trên cùng một dòng hoặc cột.

Ví dụ 4: Xác định học sinh được nhận thưởng, giả sử bạn có một bảng danh sách học sinh, trong đó:

• Cột A là Họ và tên học sinh
• Cột F là Điểm trung bình
• Cột G dùng để xác định học sinh có được nhận thưởng hay không

Công thức sử dụng tại ô G2: 
=IF(INDEX($F$2:$F$9;MATCH(A2;$A$2:$A$9;0))>=8;"Có";"Không")

Giải thích:

• MATCH(A2;$A$2:$A$9;0) dùng để xác định vị trí của học sinh trong danh sách dựa vào họ tên.
• INDEX($F$2:$F$9; … ) lấy ra điểm trung bình tương ứng với học sinh đó.

Dùng hàm IF kết hợp với INDEX và MATCH để tra cứu và so sánh dữ liệu

Hàm IF khi đi cùng với SUM được dùng để tính toán có điều kiện, tức là chỉ thực hiện phép cộng khi thỏa mãn một yêu cầu nhất định, ngược lại sẽ không trả về kết quả.

Ví dụ 5: Giả sử bạn có bảng điểm học sinh và chỉ muốn tính tổng điểm 3 môn cho những học sinh lớp 12.

Công thức sử dụng: =IF(B2=12;SUM(C2:E2);"")

Giải thích:

• Nếu học sinh thuộc lớp 12, hàm sẽ tính tổng điểm 3 môn.
• Nếu không phải lớp 12, ô kết quả sẽ để trống.

Áp dụng hàm IF kết hợp với SUM để tính toán có điều kiện trong Google Sheets

Hàm IF khi kết hợp với các hàm xử lý chuỗi như LEFT, RIGHT và MID cho phép kiểm tra nội dung văn bản dựa trên vị trí ký tự, từ đó thực hiện các thao tác lọc hoặc hiển thị dữ liệu theo điều kiện xác định trước.

Cách kết hợp này thường được sử dụng trong các trường hợp cần kiểm tra trạng thái, mã ký hiệu hoặc nội dung văn bản trong bảng dữ liệu.

Ví dụ 6: Giả sử bạn có cột kết quả học tập, trong đó các giá trị là Đậu hoặc Rớt. Yêu cầu đặt ra là chỉ hiển thị những học sinh có kết quả Rớt, các trường hợp còn lại để trống.

Công thức áp dụng: =IF(LEFT(G2;1)="R";G2;"")

Giải thích:

• Hàm LEFT(G2;1) lấy ký tự đầu tiên của nội dung trong ô G2.
• Nếu ký tự đầu là “R” (tức là Rớt) → Trả về giá trị của ô G2.
• Nếu không phải “R” → Ô kết quả sẽ để trống.

Mở rộng:

• RIGHT: Dùng để kiểm tra ký tự bên phải của chuỗi.
• MID: Dùng để kiểm tra ký tự ở vị trí bất kỳ trong chuỗi.

Sử dụng hàm IF với LEFT, RIGHT và MID để kiểm tra và xử lý chuỗi văn bản

Trong nhiều trường hợp cần lấy dữ liệu từ bảng tính khác một cách có chọn lọc, hàm IF có thể được sử dụng cùng với IMPORTRANGE để xử lý yêu cầu này.

Ví dụ 7: Giả sử bạn có thông tin chức vụ của học sinh trong bảng dữ liệu và chỉ muốn hiển thị bảng kết quả thành tích đối với học sinh giữ chức vụ lớp trưởng.

Công thức:
=IF(B8="LT";IMPORTRANGE("https://docs.google.com/spreadsheets/d/1YXrSIcoV88r_2Ao7_sNeROj3b_QoPSbMsvidyEUIJSA/edit#gid=0";"KQ!$A$1:$G$9");"")

Ý nghĩa công thức:

• Hàm IF trước tiên kiểm tra giá trị tại ô B8.
• Nếu giá trị này là LT, điều kiện được thỏa mãn.
• Khi đó, hàm IMPORTRANGE sẽ được kích hoạt để lấy dữ liệu từ một bảng tính Google Sheets khác, cụ thể là vùng ô A1 đến G9 trong trang tính có tên KQ.
• Trong trường hợp điều kiện không đúng, công thức sẽ không hiển thị dữ liệu và để trống ô kết quả.

Hàm IF kết hợp IMPORTRANGE giúp bạn lấy dữ liệu từ bảng tính khác theo điều kiện nhất định

Ví dụ 8: Sự kết hợp giữa hàm IF và VLOOKUP được dùng để xác định số lượng tập thưởng dựa trên điểm trung bình và xếp loại học sinh.

Công thức sử dụng: 
=IF(F2>=VLOOKUP(G2;$F$11:$H$14;2;0);VLOOKUP(G2;$F$11:$H$14;3;0);0)

Giải thích:

• VLOOKUP dùng để dò ngưỡng điểm và số tập thưởng tương ứng với từng xếp loại.
• IF kiểm tra xem điểm trung bình có đạt ngưỡng yêu cầu hay không.

Kết hợp hàm IF với VLOOKUP để dò tìm và xử lý dữ liệu từ các bảng tính khác

Hàm IF khi kết hợp với ISNA và VLOOKUP thường được dùng để xử lý các trường hợp dò tìm dữ liệu nhưng không tồn tại, từ đó trả về thông báo hoặc giá trị phù hợp thay vì hiển thị lỗi.

Ví dụ 9: Giả sử bạn có một bảng quy định học bổng theo xếp loại. Yêu cầu đặt ra là tự động hiển thị mức học bổng của học sinh, nếu không có dữ liệu tương ứng thì hiển thị thông báo.

Cú pháp:
=IF(ISNA(VLOOKUP(G2;$G$11:$H$13;2;0));"Không có";VLOOKUP(G2;$G$11:$H$13;2;0))

Giải thích:

• VLOOKUP dùng để dò tìm giá trị học bổng tương ứng với xếp loại trong bảng dữ liệu.
• ISNA kiểm tra kết quả dò tìm của VLOOKUP có trả về lỗi hay không.
• Nếu kết quả là lỗi N A, công thức sẽ hiển thị giá trị “Không có”.
• Nếu tìm thấy dữ liệu hợp lệ, công thức sẽ trả về mức học bổng tương ứng.

Dùng hàm IF và ISNA kết hợp với VLOOKUP để xử lý lỗi khi tìm kiếm dữ liệu

Khi cần xét nhiều điều kiện trong cùng một công thức, hàm IF có thể kết hợp với AND hoặc OR để xác định kết quả tương ứng.

Ví dụ 10: Giả sử bạn có điểm hai môn Lý và Hóa của học sinh và muốn xác định mức tiền thưởng dựa trên kết quả đạt được.

Công thức sử dụng:

• Kiểm tra đồng thời hai điều kiện (AND): =IF(AND(D2>=8;E2>=8);300000;0)
• Kiểm tra một trong hai điều kiện (OR): =IF(OR(D2>=8;E2>=8);100000;0)

Giải thích:

Hàm AND yêu cầu tất cả các điều kiện đều đúng.

• Nếu cả hai môn Lý và Hóa đều đạt từ 8 trở lên, học sinh nhận 300000.
• Nếu không thỏa điều kiện, kết quả trả về là 0.

Hàm OR chỉ cần một trong các điều kiện đúng.

• Nếu môn Lý hoặc Hóa đạt từ 8 trở lên, học sinh nhận 100000.
• Nếu cả hai môn đều không đạt, kết quả trả về là 0.

Kiểm tra nhiều điều kiện cùng lúc với hàm IF kết hợp với AND hoặc OR

Hàm IF khi kết hợp với hàm QUERY thường được dùng để lấy dữ liệu từ một vùng theo truy vấn, sau đó đánh giá điều kiện và trả về kết quả tương ứng.

Ví dụ 11: Giả sử bạn có bảng điểm học sinh và muốn xác định mức thưởng dựa trên điểm môn Toán, với điều kiện học sinh đạt từ 7 điểm trở lên mới được nhận thưởng.

Công thức sử dụng:
=ARRAYFORMULA(IF(QUERY(A2:F9;"SELECT C")>=7;250000;0))

Giải thích:

• QUERY dùng để lấy toàn bộ giá trị của cột C, tương ứng với điểm môn Toán.
• IF kiểm tra từng giá trị điểm Toán:
• Nếu điểm lớn hơn hoặc bằng 7 thì trả về 250000.
• Nếu nhỏ hơn 7 thì trả về 0.

ARRAYFORMULA giúp áp dụng công thức cho toàn bộ dải kết quả mà không cần sao chép xuống từng ô.

Hàm IF kết hợp với QUERY giúp bạn lọc và xử lý dữ liệu theo các điều kiện phức tạp

Hàm IF khi kết hợp với hàm MAX thường được sử dụng để lọc dữ liệu theo điều kiện và xác định giá trị lớn nhất trong tập dữ liệu đó.

Ví dụ 12: Giả sử bạn có danh sách học sinh thuộc các lớp 10, 11 và 12, và muốn xác định điểm trung bình cao nhất của từng lớp.

Công thức sử dụng:
=MAX(ARRAYFORMULA(IF($B$2:$B$9=H2;$F$2:$F$9)))

Giải thích:

• IF được dùng để lọc ra các điểm trung bình thuộc lớp cần xét.
• ARRAYFORMULA giúp xử lý dữ liệu dưới dạng mảng.
• MAX lấy giá trị lớn nhất trong các điểm trung bình thỏa điều kiện.
• Khi thay đổi giá trị lớp tại ô H2, công thức sẽ tự động trả về kết quả tương ứng với lớp đó.

Xác định giá trị lớn nhất trong dữ liệu với hàm IF kết hợp hàm MAX

Hàm ISBLANK hỗ trợ hàm IF trong việc nhận biết ô trống, từ đó xác định giá trị cần hiển thị.

Ví dụ 13: Trường hợp bạn có cột kết quả rớt của học sinh và muốn xác định học sinh có đủ điều kiện lên lớp hay không.

Sử dụng cú pháp: =IF(ISBLANK(G2);"Được";"Không")

Giải thích:

• ISBLANK kiểm tra ô G2 có trống hay không.
• Nếu ô G2 là ô trống, kết quả trả về là “Được”.
• Nếu ô G2 không trống, kết quả trả về là “Không”.

Dùng hàm IF và ISBLANK để kiểm tra ô dữ liệu trống trong Google Sheets

ISERROR thường được sử dụng cùng hàm IF để xử lý các phép tính có khả năng phát sinh lỗi, từ đó đưa ra kết quả phù hợp thay vì hiển thị lỗi.

Ví dụ 14: Giả sử bạn có điểm trung bình của học sinh ở hai lần đánh giá và muốn xác định học sinh có điểm trung bình lần 1 bằng 0.

Công thức sử dụng: =IF(ISERROR(F2/G2);A2;"")

Giải thích:

• Phép chia F2/G2 được thực hiện để kiểm tra dữ liệu.
• ISERROR kiểm tra phép tính có phát sinh lỗi hay không.
• Nếu phép chia gây lỗi, công thức sẽ trả về tên học sinh tại ô A2.
• Nếu không xảy ra lỗi, ô kết quả sẽ để trống.

Kết hợp hàm IF với ISERROR để xử lý lỗi trong công thức Google Sheets

Để sử dụng hàm IF hiệu quả và tránh các lỗi thường gặp trong quá trình xử lý dữ liệu, người dùng cần nắm rõ một số điểm quan trọng sau đây.

• Cần xác định rõ điều kiện kiểm tra, giá trị trả về khi đúng và giá trị trả về khi sai để công thức hoạt động chính xác.
• Luôn kiểm tra dữ liệu đầu vào nhằm tránh các lỗi không mong muốn như chia cho 0 hoặc dữ liệu trống.
• Nên kết hợp hàm IF với các hàm kiểm tra lỗi như ISERROR, ISNA hoặc IFERROR để xử lý lỗi phát sinh trong quá trình tính toán.
• Có thể lồng nhiều hàm IF để xử lý các trường hợp có nhiều điều kiện khác nhau, tuy nhiên không nên lồng quá nhiều vì sẽ khó đọc và khó bảo trì.
• Trong các trường hợp điều kiện phức tạp, nên kết hợp IF với các hàm logic như AND hoặc OR để công thức ngắn gọn và dễ hiểu hơn.
• Đối với dữ liệu lớn, cần chú ý đến hiệu suất tính toán, tránh sử dụng công thức IF quá phức tạp không cần thiết.

Trong quá trình nhập công thức, lỗi #ERROR! sẽ xuất hiện khi cú pháp của hàm không đúng hoặc định dạng dữ liệu không phù hợp với thiết lập của Google Sheets. Lỗi này thường liên quan đến việc sử dụng sai ký tự phân tách trong công thức. Để khắc phục, cần kiểm tra lại toàn bộ công thức và chỉnh sửa đúng định dạng, chẳng hạn thay dấu chấm bằng dấu phẩy trong các giá trị số thập phân nếu trang tính yêu cầu.

Tìm hiểu nguyên nhân và cách khắc phục lỗi #ERROR! trong Google Sheets

Khi Google Sheets không nhận diện được tên hàm hoặc tên đối tượng trong công thức, lỗi #NAME? sẽ được hiển thị. Nguyên nhân chủ yếu là do nhập sai tên hàm hoặc lỗi chính tả trong công thức. Cách xử lý đơn giản là rà soát lại công thức và sửa đúng tên hàm, ví dụ thay “IFF” bằng “IF” để công thức hoạt động bình thường.

Khắc phục lỗi #NAME? trong Google Sheets do nhập sai tên hàm hoặc vùng dữ liệu

Thông qua các ví dụ và trường hợp áp dụng trong bài viết, có thể thấy hàm IF đóng vai trò quan trọng trong việc kiểm tra điều kiện và xử lý dữ liệu trong Google Sheets. Khi biết cách kết hợp hàm IF với các hàm khác và chú ý đến những lỗi thường gặp, người dùng sẽ dễ dàng xây dựng các bảng tính linh hoạt, chính xác và hiệu quả hơn.

Bạn đang tìm một chiếc máy tính bảng học tập và làm việc hiệu quả? Hãy đến Siêu Thị Điện Máy - Nội Thất Chợ Lớn để lựa chọn các mẫu máy tính bảng chính hãng, cấu hình đa dạng, giá cả cạnh tranh cùng nhiều chương trình ưu đãi hấp dẫn.